blob: 31fc997eb4cbce963149757d1cf7a945bf27cc7d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id$
# Maintainer: Daniel Milde <daniel@milde.cz>
pkgbase=pypy-appdirs
pkgname=(pypy-appdirs pypy3-appdirs)
pkgver=1.4.3
pkgrel=1
pkgdesc='A small Python module for determining appropriate platform-specific dirs, e.g. a "user data dir".'
arch=('any')
url="https://github.com/ActiveState/appdirs"
license=('MIT')
makedepends=('pypy-setuptools' 'pypy3-setuptools')
source=("https://pypi.io/packages/source/a/appdirs/appdirs-$pkgver.tar.gz")
md5sums=('44c679904082a2133f5566c8a0d3ab42')
prepare() {
cp -a appdirs-$pkgver{,-py2}
}
build() {
cd "$srcdir"/appdirs-$pkgver
pypy3 setup.py build
cd "$srcdir"/appdirs-$pkgver-py2
pypy setup.py build
}
check() {
cd "$srcdir"/appdirs-$pkgver
pypy3 setup.py test
cd "$srcdir"/appdirs-$pkgver-py2
pypy setup.py test
}
package_pypy3-appdirs() {
depends=('pypy3')
cd appdirs-$pkgver
pypy3 setup.py install --prefix=/opt/pypy3 --root="$pkgdir/" --optimize=1
install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
}
package_pypy-appdirs() {
depends=('pypy')
cd appdirs-$pkgver-py2
pypy setup.py install --prefix=/opt/pypy --root="$pkgdir/" --optimize=1
install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
}
# vim:set ts=2 sw=2 et:
|