PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# $Id$
# Maintainer: Daniel Milde <daniel@milde.cz>

pkgbase=pypy-packaging
pkgname=(pypy-packaging pypy3-packaging)
pkgver=21.3
pkgrel=1
pkgdesc="Core utilities for Python packages"
arch=('any')
url="https://github.com/pypa/packaging"
license=('Apache')
makedepends=('pypy-setuptools' 'pypy3-setuptools' 'pypy-pyparsing' 'pypy3-pyparsing' 'git')
source=("git+https://github.com/pypa/packaging.git#tag=$pkgver")
md5sums=('SKIP')

prepare() {
  cp -a packaging{,-py2}
}

build() {
  cd "$srcdir"/packaging
  pypy3 setup.py build

  cd "$srcdir"/packaging-py2
  pypy setup.py build
}

package_pypy3-packaging() {
  depends=('pypy3-pyparsing' 'pypy3-six')

  cd "$srcdir"/packaging
  pypy3 setup.py install --prefix=/opt/pypy3 --root "$pkgdir"
}

package_pypy-packaging() {
  depends=('pypy-pyparsing' 'pypy-six')

  cd "$srcdir"/packaging-py2
  pypy setup.py install --prefix=/opt/pypy --root "$pkgdir"
}