blob: 61db541ce39482e5edc362f35053daf00da5d2fd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: sng <sng at hellug dot gr>
# Contributor: willemw <willemw12@gmail.com>
# Contributor: aksr <aksr at t-com dot me>
pkgname=pyradio
pkgver=0.9.3.11
pkgrel=1
pkgdesc="Internet radio player for the command line"
arch=('any')
url="https://github.com/coderholic/pyradio"
license=('MIT')
depends=('python-dnspython' 'python-requests' 'python-psutil' 'python-netifaces' 'python-rich' 'python-dateutil')
optdepends=('mplayer: as backend' 'mpv: as backend' 'vlc: as backend' 'mkvtoolnix-cli: fix mplayer recordings, add chapters to recordings')
makedepends=('python-pip' 'python-setuptools' 'python-build' 'python-installer' 'python-wheel')
source=("$pkgname-$pkgver.tar.gz::https://github.com/coderholic/$pkgname/archive/$pkgver.tar.gz")
sha256sums=('bb58052b01a726ccb6e3272b984f20a530c996f708ba45b39e15650356283c9e')
prepare() {
cd $pkgname-$pkgver
sed -i -e 's/distro = None/distro = Arch Linux (AUR)/' \
-e 's/xdg_compliant = False/xdg_compliant = True/' \
$pkgname/config
}
build() {
cd $pkgname-$pkgver
[ -d pyradio/__pycache__ ] && rm -rf pyradio/__pycache__
python -m build --wheel --no-isolation
}
package() {
cd $pkgname-$pkgver
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/pyradio/LICENSE"
install -Dm644 ./docs/*{html,md} -t "$pkgdir/usr/share/doc/pyradio"
install -Dm644 ./docs/pyradio{,_rb,_server,_rec}.1 -t "$pkgdir/usr/share/man/man1"
install -Dm644 devel/pyradio.desktop -t "$pkgdir/usr/share/applications"
install -Dm644 devel/pyradio.png -t "$pkgdir/usr/share/icons"
python -m installer --destdir="$pkgdir" dist/*.whl
}
|