PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130

# Maintainer: Carl Smedstad <carl.smedstad at protonmail dot com>

pkgname=python-aesara
_name=${pkgname#python-}
pkgver=2.9.3
pkgrel=2
pkgdesc="Library for defining, optimizing, and efficiently evaluating mathematical expressions involving multi-dimensional arrays"
arch=(any)
url="https://github.com/aesara-devs/aesara"
license=(custom)
depends=(
  python
  python-cons
  python-etuples
  python-filelock
  python-llvmlite
  python-logical-unification
  python-minikanren
  python-numpy
  python-pydot
  python-scipy
  python-setuptools
  python-sympy
  python-typing_extensions
)
makedepends=(
  python-build
  python-hatch-vcs
  python-hatchling
  python-installer
  python-wheel
)
checkdepends=(
  python-pytest
  python-numba
)
optdepends=(
  'python-jax: for graph transpilation compilation'
  'python-numba: for graph transpilation compilation'
)

source=(
  "$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/rel-$pkgver.tar.gz"
  "remove-bin-package.patch"
)
sha256sums=(
  '379a717f3edd28bd707c9bc8178c8a42bea809d8dff0e6a641002c1ac2722c97'
  '26a048c151f022411e90ff6793b61b19b0a3bf5588086d7cf9572c312be75dad'
)

_archive="$_name-rel-$pkgver"

prepare() {
  cd "$_archive"

  patch --forward --strip=1 --input="$srcdir/remove-bin-package.patch"

  sed -i 's/"hatch-vcs >=0.3.0,<0.4.0",/"hatch-vcs >=0.3.0",/' pyproject.toml
}

build() {
  cd "$_archive"

  python -m build --wheel --no-isolation
}

check() {
  cd "$_archive"

  _ignored_tests=(
    # Ignored to reduce test time - these files take 20 seconds or more per
    # file to run on my machine.
    tests/link/numba/test_elemwise.py
    tests/link/numba/test_random.py
    tests/link/numba/test_scan.py
    tests/sandbox/test_rng_mrg.py
    tests/scalar/test_basic.py
    tests/scan/test_basic.py
    tests/scan/test_rewriting.py
    tests/sparse/test_basic.py
    tests/sparse/test_var.py
    tests/tensor/nnet/test_abstract_conv.py
    tests/tensor/nnet/test_basic.py
    tests/tensor/nnet/test_batchnorm.py
    tests/tensor/nnet/test_conv.py
    tests/tensor/nnet/test_corr3d.py
    tests/tensor/nnet/test_neighbours.py
    tests/tensor/rewriting/test_basic.py
    tests/tensor/rewriting/test_elemwise.py
    tests/tensor/rewriting/test_math.py
    tests/tensor/rewriting/test_subtensor.py
    tests/tensor/signal/test_pool.py
    tests/tensor/test_basic.py
    tests/tensor/test_blas.py
    tests/tensor/test_elemwise.py
    tests/tensor/test_extra_ops.py
    tests/tensor/test_inplace.py
    tests/tensor/test_math.py
    tests/tensor/test_math_scipy.py
    tests/tensor/test_sort.py
    tests/tensor/test_subtensor.py

    # Almost all tests in these files fail - unsure why.
    tests/tensor/nnet/test_blocksparse.py
    tests/tensor/nnet/test_conv3d2d.py
    tests/tensor/nnet/test_corr.py
  )
  _ignored_tests_arg=$(printf " --ignore=%s" "${_ignored_tests[@]}")

  _deselected_tests=(
    # Failing tests - unsure why.
    tests/link/c/test_op.py::test_ExternalCOp_c_code_cache_version
    tests/link/jax/test_nlinalg.py::test_jax_basic_multiout
    tests/link/jax/test_elemwise.py::test_logsumexp_benchmark
  )
  _deselected_tests_arg=$(printf " --deselect=%s" "${_deselected_tests[@]}")

  # shellcheck disable=SC2086
  pytest \
    $_ignored_tests_arg \
    $_deselected_tests_arg
}

package() {
  cd "$_archive"

  python -m installer --destdir="$pkgdir" dist/*.whl

  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.txt
}