blob: 026614de2cbea42f3e7cb3646a23f9a2dd8ff130 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Blair Bonnett <blair dot bonnett at gmail dot com>
pkgname=python-argopy
pkgdesc='Retrieve and analyse data from the Argo network of ocean profilers'
pkgver=0.1.13
pkgrel=1
arch=('any')
url='https://argopy.readthedocs.io/'
license=('Apache')
depends=(
'python-aiohttp' 'python-erddapy' 'python-fsspec' 'python-requests'
'python-scipy' 'python-toolz' 'python-xarray'
)
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
checkdepends=('python-pytest' 'python-pytest-localftpserver')
optdepends=(
'jupyterlab: interactive visualization of available data'
'python-arrow: im-memory big data analytics'
'python-cartopy: plotting of cartographic data'
'python-dask: parallel access'
'python-ipykernel: interactive visualization of available data'
'python-matplotlib: plotting of profile data'
'python-seaborn: visualization of statistical data'
'python-tqdm: progress meters'
)
_pypi=argopy
source=(
"https://files.pythonhosted.org/packages/source/${_pypi::1}/$_pypi/$_pypi-$pkgver.tar.gz"
)
sha256sums=(
'41baa3dd92b298562ec51a52bacc37956e6b286b8d1e77fb2b39e3c170a3c1f5'
)
build() {
cd "$_pypi-$pkgver"
python -m build --wheel --no-isolation
}
check() {
cd "$_pypi-$pkgver"
pytest -v -k "not test_chunks_region and not test_open_mfdataset"
}
package() {
cd "$_pypi-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
}
|