PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Eric Engestrom <aur [at] engestrom [dot] ch>

pkgname=python-avocado-git
pkgver=101.0
pkgrel=1
pkgdesc="Set of tools and libraries to help with automated testing"
arch=('any')
url="http://avocado-framework.github.io/"
license=('GPL2')
source=("git+https://github.com/avocado-framework/avocado")
sha256sums=('SKIP')
depends=('python' 'libvirt-python')
makedepends=('git' 'python-setuptools' 'python-docutils')
conflicts=('python-avocado')
provides=("python-avocado=${pkgver%+*}")

pkgver() {
  cd avocado
  git describe --long --abbrev=10 | sed 's/-/+/; s/-/./'
}

build() {
  cd avocado
  python setup.py build
  make man
}

# FIXME: Upstream obviously doesn't run their own tests as they are always broken
false &&
check() {
  cd avocado
  make check
}

package() {
  cd avocado
  python setup.py install --root="$pkgdir/" --optimize=1 --skip-build

  install -d "$pkgdir/usr/share/man/man1/"
  install -m644 man/*.1 "$pkgdir/usr/share/man/man1/"
}