summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 2ad636071c999878c6ca54b2b993211ab38686d5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
pkgname=python-briar-wrapper
conflicts=('python-briar-wrapper-git')
pkgver=0.0.7
pkgrel=2
pkgdesc='A wrapper for the Briar headless API.'
arch=('any')
url='https://code.briarproject.org/briar/python-briar-wrapper'
license=('GNU Affero GPL')
makedepends=('python-setuptools' 'git' 'python-flit' 'python-toml')
depends=('python' 'python-websockets' 'python-requests' 'briar-headless')
source=("git+https://code.briarproject.org/briar/python-briar-wrapper.git#tag=${pkgver}"
        'address_error.patch')
sha256sums=('SKIP'
            'dff2e1645420e76c543065d3bedcfe17fc4669bb01627f6ba43a66c225b52f18')

prepare() {
  cd "${pkgname}"
  python -m flit build --setup-py

  tar -xvf dist/*.tar.gz --wildcards --no-anchored '*/setup.py' --strip=1

  # fix uncaught OSError / 'Cannot assign requested address' while waiting for briar-headless to come up
  patch -Np1 -i ../address_error.patch
}

build() {
  cd "${srcdir}/${pkgname}"

  python setup.py build
}

package() {
  cd "${srcdir}/${pkgname}"

  python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
}