blob: 982a29680cef5e85bdad5d978bcbdcbc440695be (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# shellcheck shell=bash
# -*- sh -*-
# Maintainer: Klaus Alexander Seistrup <$(echo 0x1fd+d59decfa=40 | tr 0-9+a-f=x ka-i@p-u.l)>
pkgname='python-calgebra-git'
_pkgname="${pkgname/-git/}"
_srcname="${_pkgname/python-/}"
_srcdir="${_srcname}"
pkgdesc='Python set() operations for calendar intervals (development version)'
pkgver=0.10.8.r0.gbea36e1
pkgrel=3
url="https://github.com/ashenfad/$_srcname"
arch=('any')
license=('MIT') # SPDX-License-Identifier: MIT
makedepends=(
'git'
'python-build'
'python-installer'
'python-wheel'
)
depends=(
'python'
'python-dateutil'
'python-sortedcontainers'
'python-typing_extensions'
)
optdepends=(
'python-gcsa: for working with Google Calendar'
'python-icalendar: for working with iCalendar'
'python-pandas: for converting iterables of Intervals into pandas DataFrames'
)
provides=("$_pkgname")
conflicts=("${provides[@]}")
options=('!strip')
source=("git+$url.git")
sha256sums=('SKIP')
pkgver() {
cd "$_srcdir"
git describe --long --tags \
| sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$_srcdir"
python -m build --wheel --no-isolation
}
package() {
cd "$_srcdir"
python -m installer --destdir="$pkgdir" dist/*.whl
local _site_packages='<VOID>'
_site_packages=$(python -c 'import site; print(site.getsitepackages()[0])')
rm -rf "$pkgdir$_site_packages/docs"
install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" \
./*.md docs/*.md
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" \
LICENSE
for _dir in doc licenses; do
cd "$pkgdir/usr/share/$_dir" || continue
ln -srf "$pkgname" "$_pkgname"
done
}
# eof
|