blob: 3fc1ffb6046c6a1d003aefc0079faa5f79a77d33 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Leonid Lednev <leonidledn at gmail dot com>
_name=certihound
pkgname="python-$_name-git"
pkgver=0.2.0.r12.deaf955
pkgrel=1
pkgdesc="Linux-native AD CS collector library for BloodHound CE"
arch=(any)
url="https://github.com/0x0Trace/$_name"
license=('MIT')
provides=("python-$_name")
conflicts=("python-$_name")
depends=(
'python>=3.10'
'python-ldap3>=2.9.1'
'impacket>=0.11.0'
'python-cryptography>=41.0.0'
'python-pydantic>=2.0'
'python-click>=8.1.6'
'python-rich>=13.0.0'
)
makedepends=(
'python-build'
'python-wheel'
'python-installer'
'python-setuptools>=61.0'
'git'
)
checkdepends=(
'python-pytest>=7.0.0'
'python-pytest-cov>=4.0.0'
)
source=("git+$url")
b2sums=('SKIP')
prepare() {
git -C "$_name" clean -dfx
}
pkgver() {
cd "$_name"
_tag="$(grep '^version' pyproject.toml | awk -F\" '{print $2}')" # Repo has no tags
printf "%s.r%s.%s" "$_tag" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
build() {
cd "$_name"
python -m build -wnx
}
check() {
cd "$_name"
pytest
}
package() {
cd "$_name"
python -m installer -d "$pkgdir/" dist/*.whl
install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim: ts=2 sw=2 et:
|