blob: 12a2d1667e36bcf000c1482d753e776744814bc9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
_pkgname=flask-security
pkgname=python-flask-security
pkgver=3.0.0
pkgrel=8
pkgdesc='Quick and simple security for Flask applications'
url='https://github.com/mattupstate/flask-security'
arch=('any')
license=('MIT')
depends=('python' 'python-flask' 'python-flask-login' 'python-flask-mail' 'python-flask-principal'
'python-flask-wtf' 'python-flask-babelex' 'python-itsdangerous' 'python-passlib'
'python-email-validator')
makedepends=('python-flask' 'python-flask-login' 'python-flask-mail' 'python-flask-principal'
'python-flask-wtf' 'python-flask-babelex' 'python-itsdangerous' 'python-passlib'
'python-sphinx' 'python-setuptools' 'python-pytest-runner')
#checkdepends=('python-pytest' 'python-pytest-runner' 'python-pytest-cov' 'python-pytest-cache'
#'python-mock' 'python-sqlalchemy' 'python-flask-sqlalchemy' 'python-bcrypt' 'python-pony')
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/mattupstate/flask-security/archive/${pkgver}.tar.gz)
sha512sums=('1176c154e3a4d4326fc64c6d4b986150db17b51b23003ef069596333777afd5857bc33391c46c771144422f610d669ceb96f4b5a1880b9ea374a488d6cb093f6')
prepare() {
cd ${_pkgname}-${pkgver}
sed -e 's/ --translations//' \
-e 's/ --pep8//' \
-e 's/ --flakes//' \
-i pytest.ini
}
build() {
cd ${_pkgname}-${pkgver}
python setup.py build
sphinx-build -b text docs docs/_build/text
sphinx-build -b man docs docs/_build/man
}
# TODO: test marks not compatible with latest pytest
#check() {
#cd ${_pkgname}-${pkgver}
#PYTHONPATH=. py.test
#PYTHONPATH=. py.test2
#}
package() {
cd ${_pkgname}-${pkgver}
python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
install -Dm 644 README.rst CHANGES -t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
install -Dm 644 docs/_build/text/*.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dm 644 docs/_build/man/flask-security.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
}
# vim: ts=2 sw=2 et:
|