blob: fd2fbb8a154fdb50175c22c13eb054da18aa726d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Maintainer: Brody <archfan at brodix dot de>
pkgname=python-google-cloud-bigquery
pkgver=3.46.1
pkgrel=1
pkgdesc='Google BigQuery API client library'
arch=(any)
_pkgname=${pkgname#python-}
_reponame=google-cloud-python
url=https://github.com/googleapis/${_reponame}/tree/${_pkgname}-v${pkgver}/packages/${_pkgname}
license=(Apache-2.0)
depends=(
python-dateutil
python-google-api-core
python-google-cloud-bigquery-storage
python-google-cloud-core
python-google-resumable-media
python-grpcio
python-packaging
python-protobuf
python-pyarrow
python-requests
)
makedepends=(
ipython
python-build
python-cryptography
python-installer
python-recommonmark
python-setuptools
python-sphinx
python-wheel
)
optdepends=(
ipython
'python-fastparquet: fastparquet support'
'python-llvmlite: fastparquet support'
'python-pandas: pandas support'
'python-snappy: fastparquet support'
'python-tqdm: tqdm support'
)
source=(${pkgname}-${pkgver}.tar.gz::${url%/tree*}/archive/${_pkgname}-v${pkgver}.tar.gz)
b2sums=('a7f637cc3a0162d0799ea3717304dfaff28424cf8c4e06687f9e2a2b991b9d23f89a436b19fdb3d1c1d4ece84f1ac76995f51aa6c5f6a7e1d64a7cf89087bf68')
build() {
cd ${_reponame}-${_pkgname}-v${pkgver}/packages/${_pkgname}
python -m build \
--wheel \
--no-isolation
PYTHONPATH="${PWD}" sphinx-build -b man docs/ _build
}
package() {
cd ${_reponame}-${_pkgname}-v${pkgver}/packages/${_pkgname}
python -m installer \
--destdir="${pkgdir}" \
dist/*.whl
install -Dm644 -t "${pkgdir}"/usr/share/doc/${pkgname} \
{CHANGELOG.md,README.rst}
install -Dm644 -t "${pkgdir}"/usr/share/man/man1 \
_build/${_pkgname}.1
local _site_packages
_site_packages=$(python -c 'import site; print(site.getsitepackages()[0])')
install -d "${pkgdir}"/usr/share/licenses/${pkgname}
ln -sr -t "${pkgdir}"/usr/share/licenses/${pkgname} \
"${pkgdir}"${_site_packages}/${_pkgname//-/_}-${pkgver}.dist-info/licenses/LICENSE
}
# vim: ts=2 sw=2 et:
|