blob: ed3317f18eb244f75a74878a0246cfe98615481d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Maintainer: Brody <archfan at brodix dot de>
_pkgname=python-bigquery-storage
pkgname=python-google-cloud-bigquery-storage
pkgver=2.24.0
pkgrel=1
pkgdesc='BigQuery Storage API client library'
arch=(any)
url=https://github.com/googleapis/python-bigquery-storage
license=(Apache)
depends=(
python-google-api-core
python-grpcio
python-proto-plus
python-protobuf
)
makedepends=(
python-build
python-installer
python-recommonmark
python-setuptools
python-sphinx
python-wheel
)
optdepends=(
'python-arrow: pyarrow support'
'python-fastavro: fastavro support'
'python-pandas: pandas support'
)
# checkdepends=(
# python-freezegun
# python-google-cloud-bigquery
# python-google-cloud-testutils
# python-pytest
# )
changelog=CHANGELOG.md
source=(${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz)
sha256sums=(5245f27893f4a937fe60e495f9b414b78b339728f659c81b94b755c6fb65a1d6)
build() {
cd ${_pkgname}-${pkgver}
python -m build \
--wheel \
--no-isolation
cd docs
PYTHONPATH=../ sphinx-build -b man ./ _build
}
## FIXME: test plugins conflict
# check() {
# cd ${_pkgname}-${pkgver}
# PYTHONPATH="{$PWD}" pytest -x --disable-warnings
# }
package() {
local _site=$(python -c 'import site; print(site.getsitepackages()[0])')
cd ${_pkgname}-${pkgver}
python -m installer \
--destdir="${pkgdir}" \
dist/*.whl
install -Dm644 README.rst -t "${pkgdir}"/usr/share/doc/${pkgname}/
install -Dm644 docs/_build/google-cloud-bigquery-storage.1 -t "${pkgdir}"/usr/share/man/man1/
install -d "${pkgdir}"/usr/share/licenses/${pkgname}
ln -s \
${_site}/google_cloud_bigquery_storage-${pkgver}.dist-info/LICENSE \
"${pkgdir}"/usr/share/licenses/${pkgname}
}
# vim: ts=2 sw=2 et:
|