blob: 8b6a7686f155d66b770bc74e1db6a89ed654b9b5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Blair Bonnett <blair dot bonnett @ gmail dot com>
# Contributor: richli <rich at dranek dot com>
pkgname=python-h5netcdf
pkgver=1.1.0
pkgrel=1
pkgdesc="Pythonic interface to netCDF4 via h5py"
arch=('any')
url="https://github.com/shoyer/h5netcdf"
license=('BSD')
depends=('python-h5py' 'python-packaging')
optdepends=(
'python-h5pyd: open remote datasets using the HDF REST interface'
)
makedepends=(
'python-build' 'python-installer' 'python-setuptools' 'python-setuptools-scm'
'python-setuptools-scm-git-archive' 'python-wheel'
)
checkdepends=('python-netcdf4' 'python-pytest')
_pypi=h5netcdf
source=(
"https://files.pythonhosted.org/packages/source/${_pypi::1}/$_pypi/$_pypi-$pkgver.tar.gz"
)
sha256sums=(
'932c3b573bed7370ebfc9e802cd60f1a4da5236efb11b36eeff897324d76bf56'
)
build() {
cd "$_pypi-${pkgver}"
python -m build --wheel --no-isolation
}
check() {
cd "$_pypi-${pkgver}"
PYTHONPATH="./build/lib" pytest -v --disable-warnings
}
package() {
cd "$_pypi-${pkgver}"
python -m installer --destdir="$pkgdir" "dist/$_pypi-$pkgver-"*.whl
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim: set et sw=4 ts=4 sts=4:
|