summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 0a266430053d0431719d6be2ed94ac4bf6c30175 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
# Maintainer: Elijah Gregg <lovetocode999@ctrl-c.club>
pkgname=python-makelove-git
_name="makelove"
pkgver=0.0.6.r11.g1a3de34
pkgrel=1
pkgdesc="A packaging tool for löve games"
arch=("x86_64")
url="https://github.com/pfirsich/makelove"
license=("GPL3")
makedepends=("python-setuptools")
depends=("python")
provides=("python-makelove")
conflicts=("python-makelove")
source=("git+https://github.com/pfirsich/makelove.git")
md5sums=('SKIP')

pkgver() {
    cd "$srcdir/${_name}"

    _tag=$(git tag --sort=v:refname | tail -n1)
    printf '%s.r%s.g%s' "${_tag#v}" "$(git rev-list "$_tag"..HEAD --count)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "$srcdir/${_name}"
    python setup.py build
}

package() {
    cd "$srcdir/${_name}"
    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
}