blob: 26b47f534144ba21c40f48d6695377feb560e747 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: Hugo Rodrigues <me@hugorodrigues.net>
pkgname=python-minio
pkgver=7.1.6
pkgrel=1
pkgdesc='MinIO Python SDK for Amazon S3 Compatible Cloud Storage'
arch=('any')
url='https://github.com/minio/minio-py'
license=('Apache')
depends=('python-certifi' 'python-urllib3')
makedepends=('python-setuptools' 'python-build' 'python-installer' 'python-wheel')
checkdepends=('python-pytest')
source=("$pkgname-$pkgver.tar.gz::https://files.pythonhosted.org/packages/source/m/minio/minio-$pkgver.tar.gz"
"$pkgname-$pkgver.tar.gz.asc::https://files.pythonhosted.org/packages/source/m/minio/minio-$pkgver.tar.gz.asc")
sha256sums=('54a5e6eefcc958c88c493cf116ba86e52341efab88686163594f2e9410385124'
'SKIP')
validpgpkeys=('4405F3F0DDBA1B9E68A31D2512C74390F9AAC728')
build() {
cd "minio-$pkgver"
python -m build --wheel --no-isolation
}
check() {
cd "minio-$pkgver"
pytest -x --disable-warnings
}
package() {
export PYTHONHASHSEED=0
cd "minio-$pkgver"
python -m installer --destdir="$pkgdir/" dist/*.whl
install -Dm644 README.md docs/API.md -t "$pkgdir/usr/share/doc/$pkgname/"
}
|