blob: fa3b7c7d5fe7cad4675a9cbabbc0f9791cf7e128 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Eric Langlois <eric@langlois.xyz>
pkgname=python-mujoco-py
_name=${pkgname#python-}
pkgver=2.1.2.14
pkgrel=3
pkgdesc="Python interface to the MuJoCo physics engine"
arch=('x86_64')
url="https://github.com/openai/mujoco-py"
license=('MIT' 'custom')
depends=(
'cython'
'libgl'
'mesa'
'mujoco'
'python'
'python-cffi'
'python-fasteners'
'python-glfw'
'python-imageio'
'python-numpy'
)
makedepends=('patchelf' 'python-setuptools')
optdepends=()
# Stripping breaks the generated cymj_*.so file
options=(!strip)
source=("https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz"
"$_name.patch")
sha256sums=('eb5b14485acf80a3cf8c15f4b080c6a28a9f79e68869aa696d16cbd51ea7706f'
'SKIP')
prepare() {
cd "$_name-$pkgver"
patch -p1 -i "$srcdir/$_name.patch"
sed -i'' 's/glewInitialized/glInitialized/g' \
'mujoco_py/pxd/mjrender.pxd' \
'mujoco_py/generated/wrappers.pxi'
}
build() {
cd "$_name-$pkgver"
python setup.py build
}
package() {
cd "$_name-$pkgver"
python setup.py install --root="$pkgdir" --optimize=1 --skip-build
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" "LICENSE.md"
}
|