PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: Nicholas Georgescu <nsg27@case.edu>

pkgname=python-mutmut
pkgver=3.4.0
pkgrel=1
pkgdesc="Mutation testing system for Python"
arch=('any')
url="https://github.com/boxed/mutmut"
license=('BSD-3-Clause')
depends=(
    'python>=3.10'
    'python-click'
    'python-coverage'
    'python-libcst'
    'python-pytest'
    'python-setproctitle'
    'python-textual'
    'python-toml'
)
makedepends=('python-build' 'python-installer' 'python-wheel' 'python-uv-build')
source=("https://files.pythonhosted.org/packages/source/m/mutmut/mutmut-$pkgver.tar.gz")
sha256sums=('b3b47e60828192c9f2e7737316469777f769a9163d0e384776129b80f7e8aa3e')

prepare() {
    cd "mutmut-$pkgver"
    # Relax uv_build version constraint for compatibility with Arch's version
    sed -i 's/uv_build>=0.9.5,<0.10.0/uv_build>=0.9.5/' pyproject.toml
}

build() {
    cd "mutmut-$pkgver"
    python -m build --wheel --no-isolation
}

package() {
    cd "mutmut-$pkgver"
    python -m installer --destdir="$pkgdir" dist/*.whl
    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}