blob: 8e6fa3219322e5644f18e74d48821d661ee15f8e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Mario Finelli <mario at finel dot li>
_name=onepasswordconnectsdk
pkgname=python-${_name}
pkgver=2.1.0
pkgrel=1
pkgdesc="Python SDK for 1Password Connect"
arch=(any)
url=https://github.com/1Password/connect-sdk-python
license=(MIT)
depends=(python python-dateutil python-httpx)
makedepends=(python-build python-installer python-poetry python-wheel)
checkdepends=(python-pytest python-pytest-asyncio python-pytest-cov
python-respx)
# source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz)
# we use the tarball from github because the pypi source doesn't include tests
source=(${url}/archive/v$pkgver/$_name-$pkgver.tar.gz)
sha256sums=('5e9930eae1427c6322a10365b6434f4d4a4bf5a66dab039809adf8fc43d78df3')
build() {
cd connect-sdk-python-$pkgver
python -m build --wheel --no-isolation
}
check() {
cd connect-sdk-python-$pkgver
pytest
}
package() {
cd connect-sdk-python-$pkgver
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
install -Dm0644 CHANGELOG.md "$pkgdir/usr/share/doc/$pkgname/CHANGELOG.md"
install -Dm0644 USAGE.md "$pkgdir/usr/share/doc/$pkgname/USAGE.md"
install -Dm0644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim: set ts=2 sw=2 et:
|