blob: 120a65e413ee7d997792718e51858ed7f5590741 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: George Rawlinson <grawlinson@archlinux.org>
pkgname=python-pglast
_pkgname="${pkgname#python-}"
pkgver=5.4
pkgrel=1
pkgdesc='PostgreSQL language AST and statement prettifier'
arch=('x86_64')
url='https://github.com/lelit/pglast'
license=('GPL3')
depends=('python' 'python-setuptools')
makedepends=(
'git'
'cython'
'protobuf-c'
'python-build'
'python-installer'
'python-wheel'
'python-sphinx'
)
checkdepends=('python-pytest' 'python-pytest-cov')
_commit='3e83be0a36b092f191e8c4a4f8ef54974be72414'
source=(
"$pkgname::git+$url#commit=$_commit"
'github.com-pganalyze-libpg_query::git+https://github.com/pganalyze/libpg_query'
)
b2sums=('SKIP'
'SKIP')
pkgver() {
cd "$pkgname"
git describe --tags | sed 's/^v//'
}
prepare() {
cd "$pkgname"
# setup git submodules
git submodule init
git config submodule.libpg_query.url "$srcdir/github.com-pganalyze-libpg_query"
git -c protocol.file.allow=always submodule update
}
build() {
cd "$pkgname"
python -m build --wheel --no-isolation
# generate documentation
make -C docs html
}
check() {
cd "$pkgname"
local python_version="$(python -c 'import sys; print("".join(map(str, sys.version_info[:2])))')"
PYTHONPATH="build/lib.linux-${CARCH}-cpython-${python_version}:$PYTHONPATH" pytest -v
}
package() {
cd "$pkgname"
python -m installer --destdir="$pkgdir" dist/*.whl
# documentation
install -vd "$pkgdir/usr/share/doc/$pkgname"
cp -vr docs/_build/html/* "$pkgdir/usr/share/doc/$pkgname"
}
|