blob: ff03b3cf8af6140655dcd7ddd7d3fcda766c8e75 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
# Maintainer: AlphaJack <alphajack at tuta dot io>
# Maintainer: whiteman808 <whiteman808@paraboletancza.org>
pkgname='python-pkb-client-git'
pkgver='r270.bd8d4cc'
pkgrel=1
pkgdesc='Unofficial client for the Porkbun API'
arch=('any')
license=('MIT')
url='https://github.com/infinityofspace/pkb_client'
depends=('python-requests' 'python-responses' 'python-dnspython')
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel' 'git')
source=("${pkgname}::git+${url}.git")
b2sums=('SKIP')
provides=('python-pkb-client')
conflicts=('python-pkb-client')
pkgver() {
cd "${srcdir}/${pkgname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "${srcdir}/${pkgname}"
python -m build --wheel --no-isolation
}
package() {
cd "${srcdir}/${pkgname}"
python -m installer --destdir="${pkgdir}" dist/*.whl
find "$pkgdir/usr/lib" -type d -path "*/site-packages/tests" -exec rm -rf {} +
}
|