blob: ada2451a1b3ebdb625b75ae4587d9014d07987cb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
# Maintainer: dmnmsc
pkgname=python-pybrowsers-git
_name=browsers
pkgver=1.4.0.r5.g53e6ddf
pkgrel=1
pkgdesc="Python library for detecting and launching browsers (git version)"
arch=('any')
url="https://github.com/roniemartinez/browsers"
license=('MIT')
depends=('python' 'python-pyxdg')
makedepends=('git' 'python-build' 'python-installer' 'python-wheel' 'python-uv-build')
provides=("python-pybrowsers=${pkgver}")
conflicts=('python-pybrowsers')
source=("git+https://github.com/roniemartinez/browsers.git")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$_name"
git describe --long --tags --abbrev=7 2>/dev/null | sed 's/^v//; s/\([^-]*-g\)/r\1/; s/-/./g'
}
build() {
cd "$srcdir/$_name"
python -m build --wheel --no-isolation
}
package() {
cd "$srcdir/$_name"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|