blob: 595f8f779aa213c008ff7a6be51b2787a154df80 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: KokaKiwi <kokakiwi+aur@kokakiwi.net>
pkgbase=python-pyrage
pkgname=(python-pyrage python-pyrage-stubs)
pkgver=1.2.4
pkgrel=1
pkgdesc="Python bindings for rage (age in Rust)"
arch=('x86_64')
url="https://pypi.org/project/pyrage"
license=('MIT')
depends=('python')
makedepends=('python-build' 'python-installer' 'python-wheel' 'python-setuptools' 'maturin')
source=("$pkgname-$pkgver.tar.gz::https://github.com/woodruffw/pyrage/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('d1e6bbae372bc18b892a6b4a027f8e1cd9b400825bf50067bb365b89f74ad0ab')
b2sums=('58fd9cec8724468488af9be53b2856cc22dda8dc78bca3242f87ab5c1ba384087142bc4a1557d2b39893c332518beffdfa762e3596900d8766ebf2db0b78f110')
prepare() {
cd "pyrage-$pkgver"
cargo fetch
}
build() {
cd "pyrage-$pkgver"
maturin build --release --strip --frozen
python -m build --wheel --no-isolation pyrage-stubs
}
check() {
cd "pyrage-$pkgver"
rm -rf "$srcdir/_test"
python -m installer --destdir="$srcdir/_test" target/wheels/*.whl
PYTHONPATH="$srcdir/_test"$(python -c 'import site; print(site.getsitepackages()[0])') \
python -m unittest
}
package_python-pyrage() {
cd "pyrage-$pkgver"
python -m installer --destdir="$pkgdir" target/wheels/*.whl
install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
package_python-pyrage-stubs() {
arch=('any')
cd "pyrage-$pkgver"
python -m installer --destdir="$pkgdir" pyrage-stubs/dist/*.whl
install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
export RUSTUP_TOOLCHAIN=${RUSTUP_TOOLCHAIN:-stable}
|