PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

# Maintainer: Lucki <https://aur.archlinux.org/account/Lucki>
# Contributor: Yigit Sever <yigit at yigitsever dot com>
# shellcheck shell=bash
# shellcheck disable=SC2034,SC2154

pkgname=python-pyrdfa3
_name=pyRdfa3
pkgver=3.6.2
pkgrel=1
pkgdesc="Python distiller/parser library"
arch=('any')
url="https://github.com/prrvchr/pyrdfa3"
license=('custom')
depends=('python-rdflib' 'python-html5lib' 'python-simplejson' 'python-isodate')
makedepends=(python-build python-installer python-wheel)
source=("https://github.com/prrvchr/$_name/releases/download/v$pkgver/$_name-$pkgver.tar.gz"
        "$pkgname.license::https://github.com/prrvchr/$_name/raw/master/LICENSE")
sha256sums=('73681dab957f60901696767388b956a5769c730bc451da6ffb2f0e36f18314c2'
            '18e8c2a924d44bdfdce3055db70bd4de7fad7f1d60df29458755a64bcb04766f')

build() {
    cd "$_name-$pkgver" || exit 1
    python -m build --wheel --no-isolation
}

package() {
    install -Dm644 "$pkgname.license" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

    cd "$_name-$pkgver" || exit 1
    python -m installer --destdir="$pkgdir" dist/*.whl
}