blob: a0dc6bad3bbef201179a22fff1aa1f631fee908e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Maintainer: peippo <christoph+aur@christophfink.com>
pkgname=python-pyrosm
_name=${pkgname#python-}
pkgdesc="A Python tool to parse OSM data from Protobuf format into GeoDataFrame."
url="https://pyrosm.readthedocs.io/"
pkgver=0.15.0
pkgrel=1
arch=("x86_64")
license=("MIT")
makedepends=(
"clang"
"python-build"
"python-installer"
"python-setuptools"
"python-wheel"
)
depends=(
"cython"
"python"
"python-certifi"
"python-cykhash"
"python-geopandas"
"python-numpy"
"python-pandas"
"python-protobuf"
"python-rapidjson"
"python-shapely"
)
optdepends=(
"python-igraph"
"python-networkx"
"python-pandana"
"python-pandarm"
"python-pyarrow"
)
checkdepends=(
"${optdepends[@]}"
"python-black"
"python-osmnx"
"python-pyosmium"
"python-pytest"
"python-pytest-cov"
"python-requests"
)
source=(
"https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz"
"${pkgname}-${pkgver}_LICENSE::https://raw.githubusercontent.com/HTenkanen/pyrosm/v${pkgver}/LICENSE"
"${pkgname}-sdist-tests.patch::https://github.com/${_name}/${_name}/pull/423.patch"
)
b2sums=(
"63613c4bab4c5c45777ee85e48c8f2ddf56c516226da705aa4beeca914472284974e4b1fc5653db4c1e4f32fc43f901072c680320b5a91f0dd3da8aad164f948"
"f6b1ef1a7226efb7c32b58e56a939f0b843fa03bd0cbea401482407587aac1aec8225e83f0fc7cbf10f91dabb4953814c2edc2e0c326cbb887f25a29c7806253"
"90efa0d485143af63041c0e9739c4b616f74a5f62ec7bb0dfbb9c1a81d1e6ad33827400e98d303d5325559d62cd06d8622175fbe531d1ac9bd8dd1909cf3d950"
)
prepare(){
cd "${srcdir}"/${_name}-${pkgver}
patch --forward --strip=1 --input "${srcdir}/${pkgname}-sdist-tests.patch"
}
build() {
cd "${srcdir}"/${_name}-${pkgver}
cythonize -3 --force pyrosm/*.pyx
python setup.py build_ext --inplace
python -m build --wheel --no-isolation
}
check() {
cd "${srcdir}"/${_name}-${pkgver}
local python_version=$(python -c 'import sys; print("".join(map(str, sys.version_info[:2])))')
export PYTHONPATH="${srcdir}/${_name}-${pkgver}/build/lib.linux-${CARCH}-cpython-${python_version}"
python -m pytest
}
package() {
cd "${srcdir}/${_name}-${pkgver}"
python -m installer --destdir="$pkgdir" dist/*.whl
cd "${srcdir}"
install -Dm644 "${pkgname}-${pkgver}_LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|