PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Rafael Fontenelle <rafaelff@gnome.org>
_name=pytest-pylint
pkgname=('python-pytest-pylint' 'python2-pytest-pylint')
pkgbase=python-$_name
pkgver=0.14.1
pkgrel=1
pkgdesc="pytest plugin to check source code with pylint"
arch=(any)
url="https://github.com/carsongee/pytest-pylint"
license=('MIT')
makedepends=(python-pytest python-pylint python2-pytest python2-pylint)
source=("https://pypi.org/packages/source/${_name:0:1}/$_name/$_name-$pkgver.tar.gz"
        'https://raw.githubusercontent.com/carsongee/pytest-pylint/master/LICENSE')
sha256sums=('8c38ea779e540e27ec4378b0820d906006e09f4ac834defbd886abbf57c7d2ec'
            '25b3eef02225972bdfe2c043ab26eabb5c0ce9730a9b8ce366855d9da36c8995')

prepare() {
  cp -a $_name-$pkgver{,-py2}
}

build() {
  cd "$srcdir/$_name-$pkgver"
  python setup.py build

  cd "$srcdir/$_name-$pkgver-py2"
  python2 setup.py build
}

package_python-pytest-pylint() {
  depends=(python-pytest python-pylint)
  cd "$srcdir/$_name-$pkgver"
  python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
  install -Dvm644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_python2-pytest-pylint() {
  depends=(python2-pytest python2-pylint)
  cd "$srcdir/$_name-$pkgver-py2"
  python2 setup.py install --root="$pkgdir/" --optimize=1 --skip-build
  install -Dvm644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}