summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b4d8948a64d5706ddc44f2244d6608009ada6aef (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: xiretza <xiretza+aur@xiretza.xyz>

_srcname=pythondata-cpu-blackparrot
pkgname="python-$_srcname-git"
pkgver=2020.08.r1.g4264d9b0
pkgrel=1
pkgdesc="Python module containing system_verilog files for blackparrot cpu (for use with LiteX)"
arch=(any)
url="https://github.com/litex-hub/pythondata-cpu-blackparrot"
license=('BSD')
depends=(python)
makedepends=(git python-setuptools)
provides=("${pkgname%%-git}=$pkgver")
conflicts=("${pkgname%%-git}")
source=("git+$url")
sha256sums=('SKIP')

pkgver() {
  cd "$_srcname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$_srcname"
  python setup.py build
}

package() {
  cd "$_srcname"
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build

  install -Dm644 "${_srcname//-/_}/system_verilog/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set et ts=2 syntax=PKGBUILD: