blob: d4e0ca61c95953d92a36bc51c89b83dda816c2bc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: David Runge <dvzrv@archlinux.org>
_name=pythonfinder
pkgname=python-pythonfinder
pkgver=2.1.0
pkgrel=1
pkgdesc="Cross Platform Search Tool for Finding Pythons"
arch=(any)
url="https://github.com/sarugaku/pythonfinder"
license=(MIT)
depends=(
python
python-packaging
)
makedepends=(
python-build
python-installer
python-setuptools
python-wheel
)
checkdepends=(
git
python-click
python-pytest
)
optdepends=('python-click: for CLI')
source=(
$_name-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz
)
sha512sums=('b2240eda4a44a9954f72f33039854f2aeec6dbb73ffa428a457380109b4b370ecd237bf0ee1e8ac9bc5ae6564bf1464f435eac3a3d0bd5dbe49a9fde4fb6e872')
b2sums=('47da26aac3e1b325dfc3656539c96e6137279f89590fa1f59ee9aa55873c3dc00779c87369e2edd31eba62fafbf27ce5e1faf96e1f7389dfb0d0c10d0fa133d5')
build() {
cd $_name-$pkgver
python -m build --wheel --no-isolation
}
check() {
local _site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
cd $_name-$pkgver
# install to temporary location, as importlib is used
python -m installer --destdir=test_dir dist/*.whl
export PYTHONPATH="test_dir/$_site_packages:$PYTHONPATH"
pytest -vv -c /dev/null
}
package() {
cd $_name-$pkgver
python -m installer --destdir="$pkgdir" dist/*.whl
install -vDm 644 {CHANGELOG,README}.rst -t "$pkgdir/usr/share/doc/$pkgname/"
install -vDm 644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|