summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6ba8e267261f8de94e100753a2e1a77747a1c7bf (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
# Maintainer: BrainDamage
#             adapted from package python2-scikit-rf-git
pkgname="python-scikit-rf-git"
pkgver=0.15.r10.g0af2575
pkgrel=1
pkgdesc="Scikit-rf (aka skrf) is a python package for RF/Microwave engineering"
arch=(any)
url="http://scikit-rf-web.readthedocs.org"
license=("BSD")
depends=("python" "python-numpy" "python-scipy" "python-matplotlib")
makedepends=("git")
provides=("python-scikit-rf")
conflicts=("python-scikit-rf")
optdepends=(
	"python-pyvisa: for instrument control"
	"python-pandas: for xls export"
	"python-xlrd: for xls reading"
	"python-xlwt: for xls writing"
	"ipython: for interactive shell"
)
source=("git+https://github.com/scikit-rf/scikit-rf.git")

pkgver() {
	cd "$srcdir/scikit-rf"
	git describe --tags | sed 's/^v//; s/-/.r/; s/-/./'
}

build () {
	cd "$srcdir/scikit-rf"
	python setup.py build
}

package() {
	cd "$srcdir/scikit-rf"
	python setup.py install --root="$pkgdir/" --prefix="/usr"
}
md5sums=('SKIP')