blob: 8f030090d5c3e1c8c79c9cc84b95fc34b2298a8c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: a821 at mail de
# Contributor: Chih-Hsuan Yen <yan12125@archlinux.org>
pkgname=python-scramp
pkgver=1.4.8
_commit=3855c02b79344f8abc82d3fbdfa28220443dc602
pkgrel=1
pkgdesc="Python implementation of the SCRAM protocol"
arch=(any)
url='https://codeberg.org/tlocke/scramp'
license=('MIT-0')
depends=(python python-asn1crypto)
makedepends=(
git
python-build
python-installer
python-hatchling
python-setuptools
python-versioningit
python-wheel
)
checkdepends=(python-pytest python-pytest-mock python-passlib)
source=("git+$url.git?signed#commit=$_commit")
sha256sums=('58f26263c674c2aac16314b6314d6e5550133c6bba774c89596fdfec6dfd46ea')
validpgpkeys=(
'D5681B7EC7292511C4CC1450892B00AB699851E8' # Tony Locke <tlocke@tlocke.org.uk>, proven by https://keybase.io/tlocke
)
build() {
cd scramp
python -m build --wheel --no-isolation
}
check() {
cd scramp
# install to temporary dir
local _pyver=$(python -c 'import sys; print(*sys.version_info[:2], sep=".")')
python -m installer --destdir=temp dist/*.whl
PYTHONPATH=temp/usr/lib/python$_pyver/site-packages pytest
}
package() {
cd scramp
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
}
|