blob: af4a241d6f9910868815bf5bdeae4a81520a9342 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Claudia Pellegrino <aur ät cpellegrino.de>
pkgname=python-soxr
pkgver=0.3.7
pkgrel=3
pkgdesc='High quality, one-dimensional sample-rate conversion library for Python'
arch=('x86_64')
url='https://github.com/dofuuz/python-soxr'
license=('LGPL-2.1-or-later')
depends=(
'glibc'
'libsoxr'
'python'
'python-numpy'
)
checkdepends=('python-pytest')
makedepends=(
'cython'
'python-build'
'python-installer'
'python-oldest-supported-numpy'
'python-setuptools'
'python-setuptools-scm'
'python-wheel'
)
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/dofuuz/python-soxr/archive/v${pkgver}.tar.gz"
)
sha512sums=(
'da9cc246d20c904e18fa01dfc94b0af8b430bb3d9235ab42a042ef120ec789e960a63f8e15dd79f80e9a3107ea20ebbad22f4861011ddca77ec6179fa3e6d363'
)
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
rm -rf libsoxr
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
export SETUPTOOLS_SCM_PRETEND_VERSION="${pkgver}"
python -m build --wheel --no-isolation \
-C=--build-option=--use-system-libsoxr
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}"
python_version="$(
python -c 'import sys; print("".join(map(str, sys.version_info[:2])))'
)"
export PYTHONPATH="build/lib.linux-${CARCH}-cpython-${python_version}"
python -m pytest tests/
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
python -I -m installer --destdir="${pkgdir}" dist/*.whl
install -D -m 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" \
"${srcdir}/${pkgname}-${pkgver}/LICENSE.txt"
}
|