blob: 0c3a2d24e5c451672cf0662c9d15d38a0b54e2e2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Contributor: Lex Black <autumn-wind@web.de>
# Contributor: David Scholl <djscholl at gmail dot com>
_module="tablib"
pkgname="python-${_module}"
pkgver=3.6.1
pkgrel=1
pkgdesc="Format-agnostic tabular data library (XLS, JSON, YAML, CSV)"
arch=("any")
url="http://python-tablib.org"
license=("MIT")
depends=(python)
makedepends=(python-build python-installer python-wheel python-setuptools-scm)
checkdepends=("python-pytest-cov" "python-tabulate"
"python-odfpy" "python-pandas" "python-xlrd"
"python-xlwt" "python-openpyxl" "python-pyaml")
optdepends=("python-tabulate: cli interface"
"python-odfpy: for ODS support"
"python-pandas: for pandas support"
"python-xlrd: for XLS support (extract data)"
"python-xlwt: for XLS support (create spreadsheets)"
"python-openpyxl: for XLSX support"
"python-pyaml: for YAML support")
source=(https://files.pythonhosted.org/packages/source/${_module::1}/$_module/$_module-$pkgver.tar.gz)
sha256sums=('040685fde11e9237675f43e985edb94b63250a5e9236f89d561ce6fb1465b839')
build() {
cd "${_module}-${pkgver}"
python -m build --wheel --no-isolation
}
check() {
cd "${_module}-${pkgver}"
PYTHONPATH="$PWD/build/lib:$PYTHONPATH" py.test
}
package() {
cd "${_module}-${pkgver}"
python -m installer --destdir="$pkgdir" dist/*.whl
install -D -m644 "${srcdir}/${_module}-${pkgver}/LICENSE" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|