blob: 81ae4d337070fbebf06ec22c7734d955eaffbfb9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# Maintainer: Niklas <niklas@n1klas.net>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Thomas Dziedzic < gostrc at gmail >
pkgbase=python-tornado-4.4
pkgname=('python-tornado-4.4' 'python2-tornado-4.4')
pkgver=4.4.3
pkgrel=2
pkgdesc='open source version of the scalable, non-blocking web server and tools'
arch=('i686' 'x86_64')
url='http://www.tornadoweb.org/'
license=('Apache')
makedepends=('python-setuptools' 'python2-setuptools')
checkdepends=('python-pycurl' 'python2-pycurl' 'python-mock' 'python2-mock' 'python-twisted'
'python2-twisted' 'python2-futures' 'python2-singledispatch' 'python2-backports-abc'
'python2-trollius' 'python2-monotonic' 'python-service-identity' 'python2-service-identity')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/tornadoweb/tornado/archive/v$pkgver.tar.gz"
0001-use_system_ca_certificates.patch)
sha512sums=('280503bce6b3517beace3dcf55b3e671b74064dd022b7f846fd697335f720a8f445d7ba1ffe230dff612a9160a1ed48b333b77dda3249207fc7f3c5a30948d57'
'a6422735bdce26246088d38aec55042627a1800329847aba54ca85453dcefcdde631519b57088dd441a42a4c341e7f07c73ab6b73d8404869b67ee4107bde912')
prepare() {
cd tornado-$pkgver
patch -p1 -i ../0001-use_system_ca_certificates.patch
cd "$srcdir"
cp -a tornado-$pkgver{,-py2}
# python -> python2 rename
find tornado-$pkgver-py2 -name '*py' -exec sed -e 's_#!/usr/bin/env python_&2_' -i {} \;
}
build() {
cd tornado-$pkgver
python setup.py build
cd ../tornado-$pkgver-py2
python2 setup.py build
}
check() {
(
cd tornado-$pkgver
python setup.py install --root="$PWD/tmp_install" --optimize=1
export PYTHONPATH="$PWD/tmp_install/usr/lib/python3.7/site-packages:$PYTHONPATH"
cd tmp_install
python -m tornado.test.runtests
python -m tornado.test.runtests --ioloop=tornado.platform.select.SelectIOLoop
python -m tornado.test.runtests --httpclient=tornado.curl_httpclient.CurlAsyncHTTPClient
python -m tornado.test.runtests --ioloop_time_monotonic
python -m tornado.test.runtests --ioloop=tornado.platform.twisted.TwistedIOLoop
python -m tornado.test.runtests --ioloop=tornado.platform.asyncio.AsyncIOLoop
python -m tornado.test.runtests --resolver=tornado.netutil.ThreadedResolver
) || warning "Tests failed"
(
cd tornado-$pkgver-py2
python2 setup.py install --root="$PWD/tmp_install" --optimize=1
export PYTHONPATH="$PWD/tmp_install/usr/lib/python2.7/site-packages:$PYTHONPATH"
cd tmp_install
python2 -m tornado.test.runtests
python2 -m tornado.test.runtests --ioloop=tornado.platform.select.SelectIOLoop
python2 -m tornado.test.runtests --httpclient=tornado.curl_httpclient.CurlAsyncHTTPClient
python2 -m tornado.test.runtests --ioloop_time_monotonic
python2 -m tornado.test.runtests --ioloop=tornado.platform.twisted.TwistedIOLoop
python2 -m tornado.test.runtests --ioloop=tornado.platform.asyncio.AsyncIOLoop
python2 -m tornado.test.runtests --resolver=tornado.netutil.ThreadedResolver
) || warning "Tests failed"
}
package_python-tornado-4.4() {
depends=('python')
optdepends=('python-pycurl: for tornado.curl_httpclient'
'python-twisted: for tornado.platform.twisted')
# 'python-pycares: an alternative non-blocking DNS resolver'
provides=('python-tornado=4.4')
conflicts=('python-tornado')
cd tornado-$pkgver
python setup.py install --root="$pkgdir" --optimize=1
}
package_python2-tornado-4.4() {
depends=('python2-singledispatch' 'python2-backports-abc')
optdepends=('python2-futures: recommended thread pool and for tornado.netutil.ThreadedResolver'
'python2-monotonic: enable support for a monotonic clock'
'python2-pycurl: for tornado.curl_httpclient'
'python2-twisted: for tornado.platform.twisted')
# 'python2-pycares: an alternative non-blocking DNS resolver'
provides=('python2-tornado=4.4')
conflicts=('python2-tornado')
cd tornado-$pkgver-py2
python2 setup.py install --root="$pkgdir" --optimize=1
}
|