blob: 99f681953b40924eb7df690ac0d44988f316659a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
# Maintainer: Auto update bot <auto-update-bot@arch4edu.org>
# Contributor: Brad Pitcher <bradpitcher@gmail.com>
# Contributor: Jelle van der Waa <jelle@archlinux.org>
_base=trimesh
pkgname=python-${_base}
pkgver=4.3.1
pkgrel=1
pkgdesc="Import, export, process, analyze and view triangular meshes"
arch=(any)
url="https://trimsh.org"
license=(MIT)
depends=(python-numpy)
makedepends=(python-build python-installer python-setuptools python-wheel)
# checkdepends=(python-pytest python-scipy python-lxml python-rtree python-networkx
# python-jsonschema python-pillow python-requests python-shapely python-pyinstrument
# python-collada python-svg.path python-mapbox-earcut) # python-sympy python-msgpack python-pyglet openscad
optdepends=('python-scipy: convex hulls'
'python-lxml: handle XML better and faster than built- in XML'
'python-networkx: graph operations'
'python-shapely: vector path handling'
'python-rtree: vector path handling'
'python-httpx: network requests'
'python-sympy: do analytical math'
'python-xxhash: hash ndarrays faster than built-in MD5/CRC'
'python-chardet: encoding'
'python-colorlog: print logs with colors'
'python-pillow: load images'
'python-svg.path: handle SVG format path strings'
'python-jsonschema: validate JSON schemas like GLTF'
'python-collada: parse collada/dae/zae files'
'python-pyglet: preview windows'
'python-fcl: collision queries between meshes'
'python-meshio: load mesh formats'
'python-scikit-image: for voxel ops'
'python-mapbox-earcut: triangulate polygons'
'python-psutil: get memory usage'
'gmsh: gmsh file support'
'python-ruff: static code analyzer'
'python-pytest: test runner'
'python-pyinstrument: sampling based profiler') # python-xatlas python-glooey
source=(${_base}-${pkgver}.tar.gz::https://github.com/mikedh/${_base}/archive/${pkgver}.tar.gz)
sha512sums=('01d7bcca7c1d36488f236a45481ed0cda2b63cd4a1308b0067ba95392b2517df143e3afb93c8632ad117e2dfea12e3eec80c057f8367a465a8f26b554d29614c')
build() {
cd ${_base}-${pkgver}
python -m build --wheel --skip-dependency-check --no-isolation
}
# check() {
# cd ${_base}-${pkgver}
# python -m venv --system-site-packages test-env
# test-env/bin/python -m installer dist/*.whl
# test-env/bin/python -m pytest
# }
package() {
cd ${_base}-${pkgver}
PYTHONPYCACHEPREFIX="${PWD}/.cache/cpython/" python -m installer --destdir="${pkgdir}" dist/*.whl
install -D -m644 LICENSE.md "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
}
|