blob: 361edbfbc1ce01abd160f10afd6fe64ac0238a86 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Klaus Alexander Seistrup <klaus@seistrup.dk>
# -*- sh -*-
pkgname='python-urllib3-future-git'
_pkgname="${pkgname/-git/}"
_srcname="${_pkgname/python-/}"
_srcdir="${_srcname/-/.}"
pkgver=2.7.906.r0.g37e0c967
pkgrel=2
pkgdesc='Powerful HTTP 1.1, 2, and 3 client with both sync and async interfaces (built from latest commit)'
arch=('any')
url="https://github.com/jawah/urllib3.future"
license=('MIT') # SPDX-License-Identifier: MIT
makedepends=(
'git'
'python-build'
'python-hatchling'
'python-installer'
'python-wheel'
)
depends=(
'python>=3.7'
'python-brotli'
'python-brotlicffi'
'python-h11'
'python-idna'
'python-jh2'
'python-python-socks'
'python-qh3'
'python-typing_extensions'
'python-urllib3'
'python-zstandard'
)
source=("git+$url.git")
provides=("$_pkgname")
conflicts=("$_pkgname")
sha256sums=('SKIP')
pkgver() {
cd "$_srcdir"
git describe --tags --long \
| sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$_srcdir"
# We do not wish to conflict with the original python-urllib3
env URLLIB3_NO_OVERRIDE=true python -m build --wheel --no-isolation
}
package() {
cd "$_srcdir"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm0644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}
# eof
|