PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

# Maintainer: gilcu3

_pkgname=wyoming-openwakeword
pkgname=python-$_pkgname
pkgdesc="Wyoming Server for OpenWakeWord"
pkgver=1.10.0
pkgrel=1
arch=(any)
url="https://github.com/rhasspy/wyoming-openwakeword"
license=('MIT')
depends=(python python-wyoming python-openwakeword python-onnxruntime python-tflite-runtime)
makedepends=('python-build' 'python-installer' 'python-wheel' 'python-setuptools')

source=(https://github.com/rhasspy/$_pkgname/archive/refs/tags/v$pkgver.tar.gz
        wyoming-openwakeword.conf
        wyoming-openwakeword.service)
sha256sums=('48181a8cb2a67a83b0ad3b87390b4c753b107a59713d96afcc7d5b3db80855f7'
            '522aa6621f5a69eb1e60b0be483859c3611f43fb071c310c3ab4a74a7e0637a7'
            '23b19f25f5d5d5d734f3fbd2fd16a794e907df8ba80d0612debe0c45515343b5')

build() {
  cd $_pkgname-$pkgver
  python -m build --wheel --no-isolation
}

package() {
  cd $_pkgname-$pkgver
  python -m installer --destdir="$pkgdir" dist/*.whl

  install -Dm644 ../wyoming-openwakeword.service -t "$pkgdir/usr/lib/systemd/system"
  install -Dm644 ../wyoming-openwakeword.conf "$pkgdir/etc/conf.d/wyoming-openwakeword"
}