blob: 883f77d343e5b255bd14592ef4fb4fab2f2cc013 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Original maintainer: Stuart Mumford <stuart@cadair.com>
# Current maintainer: Corentin Cadiou <contact@cphyc.me>
pkgname=python-yt
_module_name=yt
pkgver=4.3.1
pkgrel=1
pkgdesc="A community-developed analysis and visualization toolkit for volumetric data."
arch=(any)
url="http://yt-project.org"
license=('BSD')
depends=(
'python-cmyt'
'python-ewah-bool-utils'
'python-matplotlib'
'python-more-itertools'
'python-numpy'
'python-pillow'
'python-sympy'
'python-tomli-w'
'python-tqdm'
'python-typing_extensions'
'python-unyt'
)
makedepends=(
'cython'
'python-build'
'python-installer'
'python-wheel'
)
optdepends=(
'jupyterlab: interactive analysis'
'openmp: multithred support'
'python-astropy: reading FITS files'
'python-f90nml: reading RAMSES namelist files'
'python-mpi4py: parallelism support'
'python-netcdf4: read netCDF-backed datasets'
'python-pandas: support downloading sample datasets '
'python-pooch: support downloading sample datasets'
'python-scipy: KDtree-accelerated spatial indexing'
'python-xarray: input/output to xarray format'
'python-glue: input/output to glueviz format'
)
options=(!emptydirs)
source=("https://pypi.io/packages/source/y/${_module_name}/${_module_name}-${pkgver}.tar.gz")
sha256sums=('7b6db5c336dc22dd2212bb17c3b18f42cfe144bb1f6c3dda0dcd47eb77195e0e')
build() {
cd "$srcdir/${_module_name}-$pkgver"
python -m build --wheel --no-isolation
}
package() {
cd "$srcdir/${_module_name}-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
install -D -m644 COPYING.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim:set ts=2 sw=2 et:
|