summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b4b7df42023d73fbd080a33396ef22475cea595c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
# Maintainer : Yen Chi Hsuan <yan12125@gmail.com>
# Contributor: jyantis <yantis@yantis.net>
# Contributor: Rob McCathie <archaur at rmcc dot com dot au>
# Contributor: Yanus Poluektovich <ypoluektovich@gmail.com>
# Contributor: Kyle Keen <keenerd@gmail.com>
# Contributor: St├ęphane Gaudreault <stephane@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: simo <simo@archlinux.org>

pkgname=python2-imaging
pkgver=1.1.7
pkgrel=13
pkgdesc="PIL. Provides image processing capabilities for python"
arch=('i686' 'x86_64' 'armv7h' 'armv6h' 'armv6l')
url="http://www.pythonware.com/products/pil/index.htm"
license=('custom:"pil"')
depends=('python2' 'libjpeg' 'freetype2' 'lcms')
makedepends=('tk' 'sane')
optdepends=('tk: for the ImageTK module'
            'sane: for the ImageSane module')
provides=("pil=${pkgver}")
conflicts=('pil')
replaces=('pil')
source=(http://effbot.org/downloads/Imaging-${pkgver}.tar.gz
        ftheaders.patch)
md5sums=('fc14a54e1ce02a0225be8854bfba478e'
         '8e38bfc967145c5467b57f40ceed63e7')

prepare() {
  cd "${srcdir}/Imaging-${pkgver}"

  patch -F 0 -N -p1 -i ../ftheaders.patch
}

build() {
  cd "${srcdir}/Imaging-${pkgver}"

  # FS#33452
  export CFLAGS="$CFLAGS -fno-strict-aliasing"

  python2 setup.py build_ext
  cd Sane
  python2 setup.py build_ext
}

package() {
  cd "${srcdir}/Imaging-${pkgver}"
  python2 setup.py install --root="${pkgdir}" --optimize=1

  pushd Sane
  python2 setup.py install --root="${pkgdir}" --optimize=1
  popd

  install -dm755 "${pkgdir}/usr/include/python2.7/"
  install -m644 -t "${pkgdir}/usr/include/python2.7/" libImaging/*.h

  # do not have files ending in .py in /usr/bin
  for f in pildriver pilprint pilconvert pilfile pilfont; do
    mv "${pkgdir}"/usr/bin/${f}{.py,}
  done

  # Install license
  install -Dm644 "${srcdir}/Imaging-${pkgver}/README" \
                 "${pkgdir}/usr/share/licenses/${pkgname}/README"
}