PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

pkgbase=qbittorrent-enhanced-ua
pkgname=(qbittorrent-enhanced-ua qbittorrent-enhanced-ua-nox)
pkgver=5.0.2.10
pkgrel=1
pkgdesc='An advanced BitTorrent client programmed in C++, based on Qt toolkit and libtorrent-rasterbar (Enhanced Edition with original user-agent)'
arch=('x86_64')
_repo='qBittorrent-Enhanced-Edition'
url="https://github.com/c0re100/${_repo}"
license=('GPL-2.0-or-later' 'GPL-3.0-or-later')

depends=(
    'gcc-libs'
    'glibc'
    'libtorrent-rasterbar'
    'openssl'
    'qt6-base'
    'zlib'
)
makedepends=(
    'boost'
    'cmake'
    'qt6-svg'
    'qt6-tools'
)
optdepends=('python: needed for torrent search tab')

_tag="release-${pkgver}"
_snapshot="${_repo}-${_tag}"

source=("${url}/archive/${_tag}/${_snapshot}.tar.gz")
sha256sums=('425753dcdcca1a40da2996343a8ce22b45797cf4d7305db897bf61bcb56685f5')

prepare() {
    cd "${_snapshot}"
    sed -e 's|"qBittorrent Enhanced/"|"qBittorrent/"|' -i 'src/base/bittorrent/sessionimpl.cpp'
    sed -e 's|^#define QBT_VERSION_BUILD .\+|#define QBT_VERSION_BUILD 0|' -i 'src/base/version.h.in'
}

build() {
    cmake -B 'build' -S "${_snapshot}" \
        -DCMAKE_INSTALL_PREFIX=/usr

    cmake --build 'build'

    cmake -B 'build-nox' -S "${_snapshot}" \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DGUI=OFF \
        -DSYSTEMD=ON

    cmake --build 'build-nox'
}

package_qbittorrent-enhanced-ua() {
    depends+=('qt6-svg' 'hicolor-icon-theme')
    provides=('qbittorrent')
    conflicts=('qbittorrent')

    DESTDIR="${pkgdir}" cmake --install 'build'
}

package_qbittorrent-enhanced-ua-nox() {
    provides=('qbittorrent-nox')
    conflicts=('qbittorrent-nox')

    DESTDIR="${pkgdir}" cmake --install 'build-nox'
}