blob: 090e537927d726444f1f6d6f6cdff5ff0763b8a4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Maintainer: Integral <integral@member.fsf.org>
# Contributor: Kimiblock Zhou <pn3535 at icloud dot com>
pkgname=qcm-git
_pkgname=${pkgname%-git}
pkgver=1.3.2.r2.g0773e9f
pkgrel=1
pkgdesc="Qt client for netease cloud music"
arch=('x86_64')
url="https://github.com/hypengw/Qcm"
license=('GPL-2.0-or-later')
depends=(
'qt6-base'
'qt6-declarative'
'qt6-shadertools'
'qt6-grpc'
'hicolor-icon-theme'
'curl'
'openssl'
'dbus'
'ffmpeg'
'cubeb-git'
'kdsingleapplication'
'qcmbackend-git'
'qmlmaterial-git'
)
makedepends=(
'git'
'git-lfs'
'clang'
'lld'
'cmake'
'ninja'
'asio'
'pegtl'
'vulkan-headers'
)
optdepends=('qcm-ncm-plugin-git: Netease Cloud Music plugin')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=(
"git+${url}.git"
"git+https://github.com/hypengw/rstd.git"
"git+https://github.com/hypengw/ncrequest.git"
"git+https://github.com/hypengw/kstore.git"
"git+https://github.com/ilqvya/random.git"
"fix-kdsingleapplication.patch"
)
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'08a3aa14c098044dd4a129a292558df4ecfaf7bbeec0b295e5d8009c5939c422')
pkgver() {
git -C Qcm describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/v//'
}
prepare() {
patch -d Qcm -Np1 -i ../fix-kdsingleapplication.patch
}
build() {
cmake -B build \
-S Qcm \
-G Ninja \
-D CMAKE_BUILD_TYPE=None \
-D CMAKE_INSTALL_PREFIX=/usr \
-D FETCHCONTENT_FULLY_DISCONNECTED=ON \
-D FETCHCONTENT_SOURCE_DIR_RSTD="${srcdir}/rstd" \
-D FETCHCONTENT_SOURCE_DIR_NCREQUEST="${srcdir}/ncrequest" \
-D FETCHCONTENT_SOURCE_DIR_KSTORE="${srcdir}/kstore" \
-D FETCHCONTENT_SOURCE_DIR_RANDOM="${srcdir}/random" \
-D CMAKE_CXX_COMPILER=clang++ # Require clang 20+ to build
cmake --build build
}
package() {
DESTDIR="${pkgdir}" cmake --install build
}
|