summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 92a65e33b870e705f946f81865fe6292f3e08158 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
# Maintainer: queueRAM <queueRAM <at> gmail <dot> com>

pkgname=qemu-irix-git
_gitname=qemu-irix
pkgdesc="QEMU with IRIX userland support"
pkgver=v2.11.0.r2171.g939acda8af
pkgrel=1
arch=('i686' 'x86_64' 'armv7h')
license=(GPL2 LGPL2.1)
url="https://github.com/n64decomp/qemu-irix"
depends=(glib2)
makedepends=(python git)
source=(${_gitname}::git://github.com/n64decomp/qemu-irix.git)
sha256sums=('SKIP')

pkgver() {
  cd "${srcdir}/${_gitname}"
  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "${srcdir}/${_gitname}"
  mkdir -p build
}

build() (
  cd ${srcdir}/${_gitname}/build

  # headless configure with IRIX targets
  ../configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --libexecdir=/usr/lib/qemu \
    --audio-drv-list= \
    --disable-bluez \
    --disable-sdl \
    --disable-gtk \
    --disable-vte \
    --disable-opengl \
    --disable-virglrenderer \
    --disable-blobs \
    --disable-tools \
    --disable-guest-agent \
    --target-list=irix-linux-user,irixn32-linux-user,irix64-linux-user \
    --disable-capstone \
    --disable-debug-info \
    --disable-werror \
    --extra-cflags="-fmacro-prefix-map=${srcdir}=."

  make
)

package() {
  make -C "${srcdir}/${_gitname}/build" DESTDIR="${pkgdir}" install

  # remove potentially conflicting binary and docs
  cd "${pkgdir}"
  rm -r usr/lib usr/share
}