PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: jxir <jxir@web.de>
# Contributor: AndyRTR <andyrtr@archlinux.org>
# Contributor: Miguel Revilla <yo at miguelrevilla.com>
# Contributor: David Sotelo <dvsotelo at gmail.com>
# Contributor: Nuno Araujo <nuno.araujo@russo79.com>

_pkgname=qpdf
pkgname="${_pkgname}-zopfli"
pkgver=12.3.2
pkgrel=2
pkgdesc="QPDF: A Content-Preserving PDF Transformation System (with Zopfli support)"
arch=('x86_64')
url="https://github.com/qpdf/qpdf"
license=('Apache-2.0' 'Artistic-2.0')
depends=('glibc' 'gnutls' 'libgcc' 'libjpeg-turbo' 'libstdc++' 'openssl' 'zlib' 'zopfli')
makedepends=('cmake')
provides=('qpdf')
conflicts=('qpdf')
source=("https://github.com/qpdf/qpdf/releases/download/v$pkgver/${_pkgname}-${pkgver}.tar.gz")
sha256sums=('6cba2f9f2cd887d905faeb99e0e51a307b217920d1bbf3e9cfbb2e8178a2deda')

build() {
  cd ${_pkgname}-${pkgver}
  cmake -B build \
    -DCMAKE_INSTALL_PREFIX:PATH=/usr \
    -D BUILD_STATIC_LIBS:BOOL=OFF \
    -D REQUIRE_CRYPTO_GNUTLS:BOOL=ON \
    -D REQUIRE_CRYPTO_OPENSSL:BOOL=OFF \
    -D ZOPFLI:BOOL=ON \
    -D ENABLE_QTC:BOOL=ON \
    -D BUILD_DOC:BOOL=OFF
  make -C build
}

check() {
  cd ${_pkgname}-${pkgver}
  make -C build test
}

package() {
  cd ${_pkgname}-${pkgver}
  make -C build DESTDIR="${pkgdir}" install

  install -Dm644 completions/bash/qpdf "${pkgdir}/usr/share/bash-completion/completions/qpdf"
  install -Dm644 completions/zsh/_qpdf "${pkgdir}/usr/share/zsh/site-functions/_qpdf"

  rm -rf "${pkgdir}"/usr/share/doc

  mkdir -m755 -p "${pkgdir}"/usr/share/licenses/${_pkgname}
  install -m644 {Artistic-2.0,LICENSE.txt} "${pkgdir}"/usr/share/licenses/${_pkgname}/
}