blob: 48583d0bb4b0f645a13f83cc45ec1375c0c3b18e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Nick Boughton (nicholasboughton@gmail.com)
# Contributor: GFdevelop
_npmscope=quasar
_npmname=cli
_npmid="@$_npmscope/$_npmname"
pkgname="${_npmscope}-${_npmname}"
pkgver=1.3.2
pkgrel=1
pkgdesc='CLI management tool for development with the Quasar framework'
arch=('any')
url=https://quasar.dev
license=('MIT')
depends=('nodejs>=10.0.0')
makedepends=('npm>=5.0.0')
optdepends=('npm: JS package management support')
conflicts=()
source=("$pkgname-$pkgver.tar.gz::https://registry.npmjs.org/$_npmid/-/$_npmname-$pkgver.tgz")
noextract=("${source[@]%%::*}")
# Get SHASUM: curl -s "https://registry.npmjs.org/@quasar/cli" | jq '.versions."1.2.1".dist.shasum'
sha1sums=('168fb936927da58dd6ea2323b3ea6b6db2561951')
package() {
# Setting temporary cache
npm install -g --cache "$srcdir/npm-cache" --prefix "$pkgdir/usr" "${source[@]%%::*}"
# Non-deterministic race in npm gives 777 permissions to random directories.
# See https://github.com/npm/npm/issues/9359 for details.
find "${pkgdir}"/usr -type d -execdir chmod 755 {} \+
# npm gives ownership of ALL FILES to build user
# https://bugs.archlinux.org/task/63396
chown -R root:root $pkgdir
# Package contains reference to $srcdir/$pkgdir
find "${pkgdir}" -type f -name package.json -execdir sed -i '/_where/d' {} \+
# print first line (the '{' symbol) and lines from the first non-underscored key to the end
# (npm internal keys are underscored but we don't need these keys)
# This step breaks quasar. Don' do it.
#sed -i -n '1p;/ "[^_].*": {$/,$p' "$pkgdir"/usr/lib/node_modules/"$_npmid"/package.json
# Add license
install -Dm644 "$pkgdir/usr/lib/node_modules/$_npmid/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|