PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Maintainer: Otto Sabart <aur@seberm.com>
# Contributor: Olivier Medoc <o_medoc@yahoo.fr>

# Ref.: https://github.com/QubesOS/qubes-linux-utils/tree/master/archlinux

pkgbase=qubes-linux-utils
pkgname=(qubes-vm-utils qubes-vm-kernel-support)
pkgver=4.1.16
_gitname=${pkgname%-git*}
pkgrel=1
pkgdesc="Common Linux files for Qubes VM."
arch=("x86_64")
url="https://github.com/QubesOS/qubes-linux-utils"
license=('GPL')
groups=()
makedepends=(gcc make pkgconfig python-setuptools qubes-vm-xen qubes-libvchan-xen)
options=('staticlibs')
validpgpkeys=('0AF64C3B1F1214B38C8C57861FA2DBE674387CC3'  # Otto Sabart
              '0064428F455451B3EBE78A7F063938BA42CFA724'  # Marek Marczykowski-Górecki
              '427F11FD0FAA4B080123F01CDDFA1A3E36879494'  # Qubes Master Signing Key
)

source=(
    "$_gitname::git+https://github.com/QubesOS/qubes-linux-utils.git?signed#tag=v${pkgver}"
    PKGBUILD-initcpio-hook.sh
    PKGBUILD-initcpio-install.sh
)

sha512sums=(
    'SKIP'
    '5d67ae7d8c7bf166d647b7f39485a5399d17464c2f7df3d831d9e8107e83a00e8cd2214a00a9b21a76fc1edc39e79d3fa81a8d912022bb4a3ae409250e46c1cb'
    '392f562e0f1a1bbd94958c5fa3c9746529d78f1ccafc7ef85d5b0d9f06d7ec66a30467f1cd6b869a9492864586b316751e864643f1c5b82becc377bd34701246'
)


build() {
    cd "${srcdir}/${_gitname}/"
    make all
}

package_qubes-vm-utils() {
    depends=(qubes-libvchan imagemagick python-pillow python-numpy)
    install=PKGBUILD-qubes-vm-utils.install

    cd "${srcdir}/${_gitname}/"
    make install DESTDIR=$pkgdir LIBDIR=/usr/lib SYSLIBDIR=/usr/lib SBINDIR=/usr/bin
}

package_qubes-vm-kernel-support() {
    depends=(mkinitcpio grub)
    install=PKGBUILD-qubes-vm-kernel-support.install

    mkdir -p ${pkgdir}/usr/lib/initcpio/install/
    mkdir -p ${pkgdir}/usr/lib/initcpio/hooks/
    mkdir -p ${pkgdir}/usr/lib/qubes/
    mkdir -p ${pkgdir}/usr/bin/

    install -m 611 ${srcdir}/PKGBUILD-initcpio-install.sh ${pkgdir}/usr/lib/initcpio/install/qubes
    install -m 611 ${srcdir}/PKGBUILD-initcpio-hook.sh ${pkgdir}/usr/lib/initcpio/hooks/qubes

    cd "${srcdir}/${_gitname}/"
    install -m 755 dracut/full-dmroot/qubes_cow_setup.sh ${pkgdir}/usr/lib/qubes/qubes_cow_setup.sh
}