blob: 60d60aa46ff8fe1cc36b80ed4e20cd67e47dc705 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
_pkgname=alabaster.mae
_pkgver=1.6.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Load and Save MultiAssayExperiments"
arch=(any)
url="https://bioconductor.org/packages/$_pkgname"
license=('MIT')
depends=(
r-alabaster.base
r-alabaster.se
r-jsonlite
r-multiassayexperiment
r-rhdf5
r-s4vectors
)
checkdepends=(
r-biocparallel
r-testthat
)
optdepends=(
r-biocparallel
r-biocstyle
r-knitr
r-rmarkdown
r-summarizedexperiment
r-testthat
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('3dde2c4194478c89d796cec1bb5b8a31')
b2sums=('4cabb3d296470795c49e84af1ca60ca087fd3dd4b3c8e50083e3c7c1ec4ac850c72a115c61ee780aa35921c877659c2b3387d6e470ac5e088219c120916f4fbe')
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
install -d "$pkgdir/usr/share/licenses/$pkgname"
ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
}
|