blob: cd15bcd95ce1b9448461e04c18633886330ca8bf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Guoyi Zhang <guoyizhang at malacology dot net>
_pkgname=ChemmineR
_pkgver=3.54.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Cheminformatics Toolkit for R"
arch=(x86_64)
url="https://bioconductor.org/packages/${_pkgname}"
license=(Artistic2.0)
depends=(
r-base64enc
r-biocgenerics
r-dbi
r-digest
r-dt
r-ggplot2
r-gridextra
r-jsonlite
r-png
r-rcpp
r-rcurl
r-rjson
r-rsvg
r-stringi
)
makedepends=(
r-bh
swig
)
checkdepends=(
r-rsqlite
r-runit
r-snow
)
optdepends=(
r-bibtex
r-biocmanager
r-biocstyle
r-chemminedrugs
r-fmcsr
r-gplots
r-knitcitations
r-knitr
r-knitrbootstrap
r-rmarkdown
r-rpostgresql
r-rsqlite
r-scatterplot3d
r-snow
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('8dd1886811bdc4ac23c24fad60a9b238')
sha256sums=('01297549b77098b794d22158253a30989b8111a6998d1872dc993af82aaf488c')
build() {
# generate R bindings
cd "$_pkgname"
./runSwig.sh
cd ..
mkdir -p build
R CMD INSTALL "$_pkgname" -l build
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" Rscript --vanilla runTests.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
}
|