blob: c494f5c1dac3a7d123e578d63f3a18064f815298 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Guoyi Zhang <guoyizhang at malacology dot net>
_pkgname=CoGAPS
_pkgver=3.28.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Coordinated Gene Activity in Pattern Sets"
arch=(x86_64)
url="https://bioconductor.org/packages/$_pkgname"
license=('BSD-3-Clause')
depends=(
r-biocparallel
r-dplyr
r-fgsea
r-forcats
r-ggplot2
r-gplots
r-rcolorbrewer
r-rcpp
r-rhdf5
r-s4vectors
r-singlecellexperiment
r-summarizedexperiment
)
makedepends=(
r-bh
r-testthat
)
checkdepends=(
r-testthat
)
optdepends=(
r-biocfilecache
r-biocstyle
r-knitr
r-rmarkdown
r-seuratobject
r-testthat
r-xml2
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz"
"fix-openmp.patch")
md5sums=('69cccdfc0a1081fe93ab86e0ad1c9764'
'7bbd2f800d95d2a4a9c81526b637e772')
b2sums=('241983d591e9ab472f292bd96c3ed2f29fa612aebd1afd318b3e23b5e4ba16a6e970b502d888182d0a0c7a8e976e42a8d2eba79a8b26ef38b5234a9820715b9e'
'1c794cab3dab46e4e50461c0d533f3a524940210dee7b27662421082a9f198e0faa7286a1d441299857cb064940a88f24767d88c1988216c22c330c97605737e')
prepare() {
# fix OpenMP
patch -Np1 -i fix-openmp.patch
cd "$_pkgname"
autoupdate
autoconf
}
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
_check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
install -d "$pkgdir/usr/share/licenses/$pkgname"
ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
}
|