1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: peippo <christoph+aur@christophfink.com>
# Contributor: Viktor Drobot (aka dviktor) linux776 [at] gmail [dot] com
# Contributor: Grey Christoforo <first name at last name dot net>
_cranname=farver
_cranver=2.1.2
pkgname=r-${_cranname,,}
pkgver=${_cranver//[:-]/.}
pkgrel=3
pkgdesc="High Performance Colour Space Manipulation"
arch=(i686 x86_64)
url="https://cran.r-project.org/package=${_cranname}"
license=(MIT)
depends=(
r
)
optdepends=(
r-covr
)
# The unittests for `r-farver` have multiple circular
# dependency chains.
# As such, the tests can not be run on first build.
# While R packages from CRAN, generally, are well-tested
# before they are released, in some situations, you want to
# have thorough testing on your own end.
# To run the tests, first build this package without `check()`
# (i.e., as-is) to bootstrap `r-farver`. Then, on subsequent builds,
# (assumining you have a local repository that is accessible from
# the build chroot), uncomment the lines defining `checkdepends`, below,
# as well as the `check()` function further down
# checkdepends=(
# "${optdepends[@]}"
# "r-testthat>=3.0.0"
# )
source=("https://cran.r-project.org/src/contrib/${_cranname}_${_cranver}.tar.gz")
b2sums=("a596176653bb794c182035f5596f75d332ff6a48b014cc9b08ff7dcff70f1ed775e7328396c8b9d79d96e58487bf2723330a15bc8b0adc2d28c94575c4e60675")
build() {
mkdir -p "${srcdir}/build/"
R CMD INSTALL ${_cranname}_${_cranver}.tar.gz -l "${srcdir}/build/"
}
# check() {
# export R_LIBS="build/"
# R CMD check --no-manual "${_cranname}"
# }
package() {
install -dm0755 "${pkgdir}/usr/lib/R/library"
cp -a --no-preserve=ownership "${srcdir}/build/${_cranname}" "${pkgdir}/usr/lib/R/library"
if [[ -f "${_cranname}/LICENSE" ]]; then
install -Dm0644 "${_cranname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
fi
}
|