blob: 59bda6e8dd1df1c917f7f0036e0ec37b9ac3f2cc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
_pkgname=lemur
_pkgver=1.4.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Latent Embedding Multivariate Regression"
arch=(x86_64)
url="https://bioconductor.org/packages/$_pkgname"
license=('MIT')
depends=(
blas
r-biocgenerics
r-biocneighbors
r-delayedmatrixstats
r-glmgampoi
r-harmony
r-hdf5array
r-irlba
r-limma
r-matrixgenerics
r-matrixstats
r-rcpp
r-rlang
r-s4vectors
r-singlecellexperiment
r-summarizedexperiment
r-vctrs
)
makedepends=(
r-rcpparmadillo
)
checkdepends=(
r-edger
r-testthat
)
optdepends=(
r-biocstyle
r-dplyr
r-edger
r-knitr
r-rmarkdown
r-testthat
r-tidyverse
r-uwot
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('96ec610bec9c5bd78d7c19c8f7e657d0')
b2sums=('90b465d30fcc7de767abd46582417bea258880f36c12225d079679a77dfc5479c2a0b60483c7c2c9fc361ada6b07e76a2dca797d79849a61581050b5c27d3a44')
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
install -d "$pkgdir/usr/share/licenses/$pkgname"
ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
}
|