blob: 74ece1c6f1629d08b95a60522b2afd6dabda1080 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
_pkgname=oncoscanR
_pkgver=1.6.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Secondary analyses of CNV data (HRD and more)"
arch=(any)
url="https://bioconductor.org/packages/$_pkgname"
license=('MIT')
depends=(
r-genomicranges
r-iranges
r-magrittr
r-readr
r-s4vectors
)
checkdepends=(
r-testthat
)
optdepends=(
r-biocstyle
r-jsonlite
r-knitr
r-rmarkdown
r-testthat
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('c0cb4d4e3401baaaaafb15dce0fc2dfc')
b2sums=('0ad00bab6a55b37704784c61d7b3d0678e1f6a7fbed6fb2a4c66ea0cfd67637c902de74acc94b62add81361a18f689764a94f2a2f067c3cbcaa0429ef18109f3')
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
install -d "$pkgdir/usr/share/licenses/$pkgname"
ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
}
|