blob: 84783ac305580253125b75d4f155333864299045 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: sukanka <su975853527@gmail.com>
_pkgname=RoBTT
_pkgver=1.3.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Robust Bayesian T-Test"
arch=(x86_64)
url="https://cran.r-project.org/package=$_pkgname"
license=('GPL-3.0-only')
depends=(
onetbb
r-bayestools
r-bridgesampling
r-ggplot2
r-rcpp
r-rcppparallel
r-rdpack
r-rstan
r-rstantools
)
makedepends=(
r-bh
r-rcppeigen
r-stanheaders
)
checkdepends=(
r-testthat
r-vdiffr
)
optdepends=(
r-covr
r-knitr
r-rmarkdown
r-testthat
r-vdiffr
)
source=("https://cran.r-project.org/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('aa8b805fa470d5bb0845eec1cf08ddf8')
b2sums=('0e79d62fc434d8f42860e68f7da2783b28c6cfc46efc3a112fa5d2687332d340f76b66f63155d276715ac857b5941b05d916b65e80212e439da17ddaac982250')
prepare() {
# skip test that requires external files
sed -i '1a skip("Requires external files")' \
"$_pkgname/tests/testthat/test-4-diagnostics.R"
}
build() {
mkdir build
# compilation needs a lot of memory
MAKEFLAGS+=" -j1"
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
}
|